<<Combinatorica`

CFT

Virasoro data in terms via a,  ϵ1 ϵ2

Q2=((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))^2/((Subscript[ϵ, 1]) (Subscript[ϵ, 2]));

c=1+6 Q2;

B  Evaluates < 0 | LLL .... LLLL | 0 >  by commutation relations.

B[{}]:=1

B[{n_,x___}]/; n<0:=0

B[{n_,x___}]/; n==0:=D0  B[{x}]

B[{x___,n_}]/; n>0:=0

B[{x___,n_}]/; n==0:=D0  B[{x}]

B[{l___,m_,n_,r___}] /; (m≠ -n  && m≥ 0  && n<0 ) :=(m-n) B[{l,m+n,r}] +B[{l,n,m,r}]

B[{l___,m_,n_,r___}] /; (m== -n  && m≥ 0  && n<0 ) :=(m-n) B[{l,m+n,r}] +B[{l,n,m,r}]+ c m(m^2-1)/12 B[{l,r}]

Kac matrix.

Kac[n_]:=Kac[n]=Module[{par=Partitions[n]},Table[B[Join[Reverse[ par[[i]]],-par[[j]]]],{i,1,Length[par]},{j,1,Length[par]}]]

IKac[n_]:=Inverse[Kac[n]]

<w|w> as the entry Kac^(-1)[{1^n} , {1^n} ]. Uses the fact {1^n} appears last in Partitions[n]. ww[i] is the contribution from i-th descendants.

ww[n_]:=Module[{par=Partitions[n]},IKac[n][[Length[par],Length[par]]]]Λ^(4n)/((Subscript[ϵ, 1]) (Subscript[ϵ, 2]))^(2n)

Nekrasov parittion functions

DualPartition[l_]:=Module[{i},Table[Length[Select[l,(#>=i)&]],{i,1,l[[1]]}]]

DualPartition[{}]={};

get[Y_,i_]:=If[i>Length[Y],0,Y[[i]]]

arm and leg lengths

arm[Y_,{i_,j_}]:=get[Y,i]-j

leg[Y_,{i_,j_}]:=get[DualPartition[Y],j]-i

boxes[Y_]:=Join@@Module[{i,j},Table[Table[{i,j},{j,1,Y[[i]]}],{i,1,Length[Y]}]]

e[a_,Y1_,Y2_,s_]:=a-(Subscript[ϵ, 1])  leg[Y2,s] + (Subscript[ϵ, 2]) (arm[Y1,s]+1)

Contribution of a W-boson

fromWa[a_,bb_,Y1_,Y2_]:=(Times @@ ( (e[a-bb,Y1,Y2,#]((Subscript[ϵ, 1])+(Subscript[ϵ, 2])-e[a-bb,Y1,Y2,#]))&/@ boxes[Y1]))

Contribution of a U(2) vector multiplet

fromSU2V[a_,Y1_,Y2_]:=1/(fromWa[a,a,Y1,Y1]fromWa[a,-a,Y1,Y2]fromWa[-a,a,Y2,Y1]fromWa[-a,-a,Y2,Y2])

youngPairs[k_]:=youngPairs[k]=Join@@ Module[{i},Join@@ Table[Outer[List,Partitions[i],Partitions[k-i],1],{i,0,k}]]

i-instanton contribution

pure[i_]:=(Plus @@ (fromSU2V[a,#[[1]],#[[2]]]& /@ youngPairs[i]))Λ^(4i)

Comparison

Δ[a_]:=Q2/4-a^2/((Subscript[ϵ, 1])(Subscript[ϵ, 2]));

k=1;

pure[k]

ww[k]/. D0-> Δ[a]

%-%%//FullSimplify