<<Combinatorica`

CFT

Virasoro data in terms via a,  ϵ1 ϵ2

Q2=((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))^2/((Subscript[ϵ, 1]) (Subscript[ϵ, 2]));

c=1+6 Q2;

B  Evaluates < 0 | LLL .... LLLL | 0 >  by commutation relations.

B[{}]:=1

B[{n_,x___}]/; n<0:=0

B[{n_,x___}]/; n==0:=D0  B[{x}]

B[{x___,n_}]/; n>0:=0

B[{x___,n_}]/; n==0:=D0  B[{x}]

B[{l___,m_,n_,r___}] /; (m≠ -n  && m≥ 0  && n<0 ) :=(m-n) B[{l,m+n,r}] +B[{l,n,m,r}]

B[{l___,m_,n_,r___}] /; (m== -n  && m≥ 0  && n<0 ) :=(m-n) B[{l,m+n,r}] +B[{l,n,m,r}]+ c m(m^2-1)/12 B[{l,r}]

r  Evaluates < 0 | LLL .. O .. LLLL | 0 >  by commutation relations.

R[{},{}]=Z^(D1−D2−D3)

R[{n_,x___},z_]/; n<0:=0

R[{n_,x___},z_]/; n==0:=D1  R[{x},z]

R[z_,{x___,n_}]/; n>0:=0

R[z_,{x___,n_}]/; n==0:=D3  R[z,{x}]

R[{l___,m_,n_,r___},z_] /; (m≠ -n  && m≥ 0  && n<0 ) :=(m-n) R[{l,m+n,r},z] +R[{l,n,m,r},z]

R[{l___,m_,n_,r___},z_] /; (m== -n  && m≥ 0  && n<0 ) :=(m-n) R[{l,m+n,r},z] +R[{l,n,m,r},z]+ c m(m^2-1)/12 R[{l,r},z]

R[z_,{l___,m_,n_,r___}] /; (m≠ -n  && m≥ 0  && n<0 ) :=(m-n) R[z,{l,m+n,r}] +R[z,{l,n,m,r}]

R[z_,{l___,m_,n_,r___}] /; (m== -n  && m≥ 0  && n<0 ) :=(m-n) R[z,{l,m+n,r}] +R[z,{l,n,m,r}]+ c m(m^2-1)/12R[z,{l,r}]

R[{x___,m_},{y___}]/; m≥ 0 := R[{x},{m,y}] + (1+m) Z^m D2 R[{x},{y}]+  Z^(m+1)D[ R[{x},{y}],Z]

R[{x___},{m_,y___}]/; m<0 := R[{x,m},{y}] - (1+m) Z^m D2 R[{x},{y}]-  Z^(m+1)D[ R[{x},{y}],Z]

ket[n_]:=(par=Partitions[n];Table[R[Reverse[par[[i]]],{}]/.Z->1,{i,1,Length[par]}])

bra[n_]:=(par=Partitions[n];Table[R[{},-par[[i]]]/.Z->1,{i,1,Length[par]}])

Kac matrix.

Kac[n_]:=Kac[n]=Module[{par=Partitions[n]},Table[B[Join[Reverse[ par[[i]]],-par[[j]]]],{i,1,Length[par]},{j,1,Length[par]}]]

Four-point conformal block.

F4[n_]:=(bra[n]/.{D1->D4,D2->D3,D3->D}).((Inverse[Kac[n]]/.D0->D).(ket[n]/.{D1->D,D2->D2,D3->D1}))

Nekrasov parittion functions

DualPartition[l_]:=Module[{i},Table[Length[Select[l,(#>=i)&]],{i,1,l[[1]]}]]

DualPartition[{}]={};

get[Y_,i_]:=If[i>Length[Y],0,Y[[i]]]

arm and leg lengths

arm[Y_,{i_,j_}]:=get[Y,i]-j

leg[Y_,{i_,j_}]:=get[DualPartition[Y],j]-i

boxes[Y_]:=Join@@Module[{i,j},Table[Table[{i,j},{j,1,Y[[i]]}],{i,1,Length[Y]}]]

e[a_,Y1_,Y2_,s_]:=a-(Subscript[ϵ, 1])  leg[Y2,s] + (Subscript[ϵ, 2]) (arm[Y1,s]+1)

Contribution of a W-boson

fromWa[a_,bb_,Y1_,Y2_]:=(Times @@ ( (e[a-bb,Y1,Y2,#]((Subscript[ϵ, 1])+(Subscript[ϵ, 2])-e[a-bb,Y1,Y2,#]))&/@ boxes[Y1]))

Contribution of a U(2) vector multiplet

fromSU2V[a_,Y1_,Y2_]:=1/(fromWa[a,a,Y1,Y1]fromWa[a,-a,Y1,Y2]fromWa[-a,a,Y2,Y1]fromWa[-a,-a,Y2,Y2])

youngPairs[k_]:=youngPairs[k]=Join@@ Module[{i},Join@@ Table[Outer[List,Partitions[i],Partitions[k-i],1],{i,0,k}]]

Contribution of a hyper in the doublet of SU(2)

eigen[a_,Y_]:=(a +(Subscript[ϵ, 1]) #[[1]]+(Subscript[ϵ, 2]) #[[2]]) &/@ boxes[Y]

eigen[a_,Y1_,Y2_]:=eigen[a,Y1]~Join~eigen[-a,Y2]

fund[a_,Y1_,Y2_,m_]:=(Times@@((#-m)&/@eigen[a,Y1,Y2]))

i-instanton contribution

Z[i_]:=(Plus @@ ((fromSU2V[a,#[[1]],#[[2]]]fund[a,#[[1]],#[[2]],μ1 ] fund[a,#[[1]],#[[2]],μ2]fund[a,#[[1]],#[[2]],μ3]fund[a,#[[1]],#[[2]],μ4])& /@ youngPairs[i]))

Comparison

FF[n_]:=Sum[q^i F4[i],{i,0,n}]+O[q]^(n+1)

ZZ[n_]:=Sum[q^i Z[i],{i,0,n}]+O[q]^(n+1)

Δ[a_]:=Q2/4-a^2/((Subscript[ϵ, 1])(Subscript[ϵ, 2]))

μ1=m2-m1+((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))/2;μ2=m2+m1+((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))/2;

μ4=m3-m4+((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))/2;μ3=m3+m4+((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))/2;

U1factor=(1-q)^(2(((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))/2 -m2 )(((Subscript[ϵ, 1])+(Subscript[ϵ, 2]))/2-m3)/((Subscript[ϵ, 1])(Subscript[ϵ, 2])));

k=1;

FFF=FF[k]/.{D-> Δ[a],D1-> Δ[m1],D2-> Δ[m2],D3-> Δ[m3],D4-> Δ[m4]}

ZZZ=ZZ[k]

U1factor FFF-ZZZ //FullSimplify