座標の名前をつける

X={ct,r,θ,ϕ}

時空の座標の数

dim=Length[X]

計量

dss=-F[r]d[ct]^2+G[r] d[r]^2+r^2 (d[θ]^2+Sin[θ]^2 d[ϕ]^2)

計量から (Subscript[g, ij]) をよみとる

g=Table[(1/2)D[D[dss,d[X[[i]]]],d[X[[j]]]],{i,1,dim},{j,1,dim}]

g の逆行列

ginv=Inverse[g]//Simplify

Γ の式

Γ[i_,j_,k_]:=Sum[ginv[[i,m]](1/2)(D[g[[m,j]],X[[k]]]+D[g[[m,k]],X[[j]]]-D[g[[j,k]],X[[m]]]),{m,1,dim}]//Simplify

R の式

R[i_,j_,k_,m_]:=D[Γ[i,j,m],X[[k]]]-D[Γ[i,j,k],X[[m]]]+Sum[Γ[i,l,k]Γ[l,j,m]-Γ[i,l,m]Γ[l,j,k],{l,1,dim}]//Simplify

R[i_,j_]:=Sum[R[k,i,k,j],{k,1,dim}]//Simplify

(Subscript[R, ij]) はこうなる。

Table[R[i,j],{i,1,dim},{j,1,dim}]//FullSimplify

これが全部ゼロにならないといけない。

G[r]R[1,1]//Expand

F[r]R[2,2]//Expand

足すと綺麗になりそう ...

G[r]R[1,1]+F[r]R[2,2]//Expand

r G[r](G[r]R[1,1]+F[r]R[2,2])//FullSimplify

すなわち (FG)’ =0 ということ。遠方では F も G も 1 なので次のようにできる:

G[r]=1/F[r]

ここで R[3, 3] を計算すると

R[3,3]

これは (r F)' = 1 ということ。すなわち次のようにできる:

F[r]=1-a/r

再度 (Subscript[R, ij]) を確認。

Table[R[i,j],{i,1,dim},{j,1,dim}]//FullSimplify